| View previous topic :: View next topic |
| Author |
Message |
uhai
Veteran
Joined: 23 Aug 2007
Posts: 1395
Location: Eppingen, Germany
|
 Posted: Tue Aug 22, 2017 6:12 pm Post subject: [gelöst] vim-start "unschön" |
 |
|
Hallo,
ich habe versucht in vim das Syntax-Highlighting zu aktivieren. Seitdem bekomme ich folgende Meldungen beim Start von vim:
| Code: | vim
Fehler beim Ausführen von "/usr/share/vim/vim80/syntax/syncolor.vim":
Zeile 34:
E169: Befehl zu rekursiv
Zeile 54:
E169: Befehl zu rekursiv
Zeile 55:
E169: Befehl zu rekursiv
Zeile 59:
E169: Befehl zu rekursiv
Zeile 60:
E169: Befehl zu rekursiv
Zeile 61:
E169: Befehl zu rekursiv
Zeile 62:
E169: Befehl zu rekursiv
Zeile 63:
E169: Befehl zu rekursiv
Zeile 64:
E169: Befehl zu rekursiv
Zeile 65:
E169: Befehl zu rekursiv
Zeile 66:
E169: Befehl zu rekursiv
Zeile 67:
E169: Befehl zu rekursiv
Zeile 68:
E169: Befehl zu rekursiv
Zeile 69:
E169: Befehl zu rekursiv
Zeile 70:
E169: Befehl zu rekursiv
Zeile 71:
E169: Befehl zu rekursiv
Zeile 72:
E169: Befehl zu rekursiv
Zeile 73:
E169: Befehl zu rekursiv
Zeile 74:
E169: Befehl zu rekursiv
Zeile 75:
E169: Befehl zu rekursiv
Zeile 76:
E169: Befehl zu rekursiv
Zeile 77:
E169: Befehl zu rekursiv
Zeile 78:
E169: Befehl zu rekursiv
Zeile 79:
E169: Befehl zu rekursiv
Zeile 80:
E169: Befehl zu rekursiv
Zeile 81:
E169: Befehl zu rekursiv
Zeile 82:
E169: Befehl zu rekursiv
Zeile 1:
E169: Befehl zu rekursiv
Fehler beim Ausführen von "/usr/share/vim/vim80/syntax/nosyntax.vim":
Zeile 1:
E169: Befehl zu rekursiv
Fehler beim Ausführen von "/usr/share/vim/vim80/syntax/synload.vim":
Zeile 1:
E169: Befehl zu rekursiv
Fehler beim Ausführen von "/usr/share/vim/vim80/syntax/syntax.vim":
Zeile 1:
E169: Befehl zu rekursiv
Fehler beim Ausführen von "/etc/vim/vimrc.local":
Zeile 95:
E169: Befehl zu rekursiv
Fehler beim Ausführen von "/usr/share/vim/vim80/filetype.vim":
Zeile 1:
E169: Befehl zu rekursiv
Fehler beim Ausführen von "/usr/share/vim/vim80/ftplugin.vim":
Zeile 1:
E169: Befehl zu rekursiv
Fehler beim Ausführen von "/etc/vim/vimrc.local":
Zeile 1:
E169: Befehl zu rekursiv
Betätigen Sie die EINGABETASTE oder geben Sie einen Befehl ein
|
An den Konfigurationsdateien habe ich nichts geändert, nur den Aufruf aktiviert. Wenn ich in die genannten Dateien schaue kann ich den Fehler nicht finden... vim arbeitet trotz dieser Meldungen korrekt mit Syntax-Highlighting (soweit ich das erkennen kann)
Hat hier jemand den gleichen vim mit Syntax-Highlighting laufen ohne diese Meldungen?
| Code: | VIM - verbesserter Vi
~
~ Version 8.0.386
~ von Bram Moolenaar und Anderen
~ Verändert von Gentoo-8.0.0386 |
uhai
Last edited by uhai on Sat Sep 23, 2017 7:59 pm; edited 1 time in total |
|
| Back to top |
|
 |
sdoubleyou
n00b
Joined: 27 May 2016
Posts: 42
|
| Posted: Tue Aug 22, 2017 7:47 pm Post subject: |
|
|
bei mir läuft vim sauber mit syntax-Highlighting
Wie hast Du das denn aktiviert? Kann es sein, dass Du in Deiner .vimrc etwas doppelt hast?
Zeig doch mal Deine .vimrc
Ich habe es einfach in meine ~/.vimrc stehen mit
| Code: | | syntax on " Code farbig darstellen |
|
|
| Back to top |
|
|
uhai
Veteran
Joined: 23 Aug 2007
Posts: 1395
Location: Eppingen, Germany
|
| Posted: Wed Aug 23, 2017 6:06 pm Post subject: |
|
|
.vimrc:
| Code: | scriptencoding utf-8
" ^^ Please leave the above line at the start of the file.
" Default configuration file for Vim
" Written by Aron Griffis <agriffis@gentoo.org>
" Modified by Ryan Phillips <rphillips@gentoo.org>
" Modified some more by Ciaran McCreesh <ciaranm@gentoo.org>
" Added Redhat's vimrc info by Seemant Kulleen <seemant@gentoo.org>
" You can override any of these settings on a global basis via the
" "/etc/vim/vimrc.local" file, and on a per-user basis via "~/.vimrc". You may
" need to create these.
" {{{ General settings
" The following are some sensible defaults for Vim for most users.
" We attempt to change as little as possible from Vim's defaults,
" deviating only where it makes sense
set nocompatible " Use Vim defaults (much better!)
set bs=2 " Allow backspacing over everything in insert mode
set ai " Always set auto-indenting on
set history=50 " keep 50 lines of command history
set ruler " Show the cursor position all the time
set viminfo='20,\"500 " Keep a .viminfo file.
" Don't use Ex mode, use Q for formatting
map Q gq
" When doing tab completion, give the following files lower priority. You may
" wish to set 'wildignore' to completely ignore files, and 'wildmenu' to enable
" enhanced tab completion. These can be done in the user vimrc file.
set suffixes+=.info,.aux,.log,.dvi,.bbl,.out,.o,.lo
" When displaying line numbers, don't use an annoyingly wide number column. This
" doesn't enable line numbers -- :set number will do that. The value given is a
" minimum width to use for the number column, not a fixed size.
if v:version >= 700
set numberwidth=3
endif
" }}}
" {{{ Modeline settings
" We don't allow modelines by default. See bug #14088 and bug #73715.
" If you're not concerned about these, you can enable them on a per-user
" basis by adding "set modeline" to your ~/.vimrc file.
set nomodeline
" }}}
" {{{ Modeline settings
" We don't allow modelines by default. See bug #14088 and bug #73715.
" If you're not concerned about these, you can enable them on a per-user
" basis by adding "set modeline" to your ~/.vimrc file.
set nomodeline
" }}}
" {{{ Locale settings
" Try to come up with some nice sane GUI fonts. Also try to set a sensible
" value for fileencodings based upon locale. These can all be overridden in
" the user vimrc file.
if v:lang =~? "^ko"
set fileencodings=euc-kr
set guifontset=-*-*-medium-r-normal--16-*-*-*-*-*-*-*
elseif v:lang =~? "^ja_JP"
set fileencodings=euc-jp
set guifontset=-misc-fixed-medium-r-normal--14-*-*-*-*-*-*-*
elseif v:lang =~? "^zh_TW"
set fileencodings=big5
set guifontset=-sony-fixed-medium-r-normal--16-150-75-75-c-80-iso8859-1,-taipei-fixed-medium-r-normal--16-150-75-75-c-160-big5-0
elseif v:lang =~? "^zh_CN"
set fileencodings=gb2312
set guifontset=*-r-*
endif
" If we have a BOM, always honour that rather than trying to guess.
if &fileencodings !~? "ucs-bom"
set fileencodings^=ucs-bom
endif
" Always check for UTF-8 when trying to determine encodings.
if &fileencodings !~? "utf-8"
" If we have to add this, the default encoding is not Unicode.
" We use this fact later to revert to the default encoding in plaintext/empty
" files.
let g:added_fenc_utf8 = 1
set fileencodings+=utf-8
endif
" Make sure we have a sane fallback for encoding detection
if &fileencodings !~? "default"
set fileencodings+=default
endif
" }}}
" {{{ Syntax highlighting settings
" Switch syntax highlighting on, when the terminal has colors
" Also switch on highlighting the last used search pattern.
if &t_Co > 2 || has("gui_running")
syntax on
set hlsearch
endif
" }}}
" {{{ Terminal fixes
if &term ==? "xterm"
set t_Sb=^[4%dm
set t_Sf=^[3%dm
set ttymouse=xterm2
endif
if &term ==? "gnome" && has("eval")
" Set useful keys that vim doesn't discover via termcap but are in the
" builtin xterm termcap. See bug #122562. We use exec to avoid having to
" include raw escapes in the file.
exec "set <C-Left>=\eO5D"
exec "set <C-Right>=\eO5C"
endif
" }}}
" {{{ Filetype plugin settings
" Enable plugin-provided filetype settings, but only if the ftplugin
" directory exists (which it won't on livecds, for example).
if isdirectory(expand("$VIMRUNTIME/ftplugin"))
filetype plugin on
" Uncomment the next line (or copy to your ~/.vimrc) for plugin-provided
" indent settings. Some people don't like these, so we won't turn them on by
" default.
" filetype indent on
endif
" }}}
" {{{ Fix &shell, see bug #101665.
if "" == &shell
if executable("/bin/bash")
set shell=/bin/bash
elseif executable("/bin/sh")
set shell=/bin/sh
endif
endif
"}}}
" {{{ Our default /bin/sh is bash, not ksh, so syntax highlighting for .sh
" files should default to bash. See :help sh-syntax and bug #101819.
if has("eval")
let is_bash=1
endif
" }}}
" {{{ Autocommands
if has("autocmd")
augroup gentoo
au!
" Gentoo-specific settings for ebuilds. These are the federally-mandated
" required tab settings. See the following for more information:
" http://www.gentoo.org/proj/en/devrel/handbook/handbook.xml
" Note that the rules below are very minimal and don't cover everything.
" Better to emerge app-vim/gentoo-syntax, which provides full syntax,
" filetype and indent settings for all things Gentoo.
au BufRead,BufNewFile *.e{build,class} let is_bash=1|setfiletype sh
au BufRead,BufNewFile *.e{build,class} set ts=4 sw=4 noexpandtab
" In text files, limit the width of text to 78 characters, but be careful
" that we don't override the user's setting.
autocmd BufNewFile,BufRead *.txt
\ if &tw == 0 && ! exists("g:leave_my_textwidth_alone") |
\ setlocal textwidth=78 |
\ endif
" When editing a file, always jump to the last cursor position
autocmd BufReadPost *
\ if ! exists("g:leave_my_cursor_position_alone") |
\ if line("'\"") > 0 && line ("'\"") <= line("$") |
\ exe "normal! g'\"" |
\ endif |
\ endif
" When editing a crontab file, set backupcopy to yes rather than auto. See
" :help crontab and bug #53437.
autocmd FileType crontab set backupcopy=yes
" If we previously detected that the default encoding is not UTF-8
" (g:added_fenc_utf8), assume that a file with only ASCII characters (or no
" characters at all) isn't a Unicode file, but is in the default encoding.
" Except of course if a byte-order mark is in effect.
autocmd BufReadPost *
\ if exists("g:added_fenc_utf8") && &fileencoding == "utf-8" &&
\ ! &bomb && search('[\x80-\xFF]','nw') == 0 && &modifiable |
\ set fileencoding= |
\ endif
augroup END
endif " has("autocmd")
" }}}
" We don't want VIM to load their own built-in defaults, preferring ours here
" instead:
let g:skip_defaults_vim = 1
" {{{ vimrc.local
if filereadable("/etc/vim/vimrc.local")
source /etc/vim/vimrc.local
endif
" }}}
" vim: set fenc=utf-8 tw=80 sw=2 sts=2 et foldmethod=marker :
|
Außerdem habe ich noch eine vimrc.local....
Wie ich das Highlighting "scharf geschalten" habe, weiß ich nicht mehr. Vermutlich nach irgendeiner Anleitung im Internet. In den configs habe ich sicher nicht viel geändert.
uhai |
|
| Back to top |
|
|
sdoubleyou
n00b
Joined: 27 May 2016
Posts: 42
|
| Posted: Thu Aug 24, 2017 2:42 pm Post subject: |
|
|
ich habe mal Deine .vimrc bei mir getestet und alles läuft ohne Fehlermeldungen ab. Finde dadurch leider keinen Ansatz.
Ich habe bei mir unter /etc/vim/ nur eine vimrc. |
|
| Back to top |
|
|
uhai
Veteran
Joined: 23 Aug 2007
Posts: 1395
Location: Eppingen, Germany
|
| Posted: Thu Aug 24, 2017 5:44 pm Post subject: |
|
|
Ich habe eine ganze Auswahl....:
| Code: | locate vimrc
/etc/vim/vimrc
/etc/vim/vimrc.local
/usr/portage/app-editors/gvim/files/gvimrc-r1
/usr/portage/app-editors/vim-core/files/vimrc-r5
/usr/share/doc/llvm-3.9.1-r1/vimrc.bz2
/usr/share/vim/vim80/gvimrc_example.vim
/usr/share/vim/vim80/vimrc_example.vim
|
Vielleicht ist das zuviel?
uhai |
|
| Back to top |
|
|
firefly
Watchman
Joined: 31 Oct 2002
Posts: 5317
|
| Posted: Thu Aug 24, 2017 6:10 pm Post subject: |
|
|
Dsa Problem liegt zum einen in dieser Datei:
| Code: | | Fehler beim Ausführen von "/usr/share/vim/vim80/syntax/syncolor.vim": |
Scheinbar ist diese kaputt. Ich habe selbst kein vim installiert. Aber eventuell kann man deine Version mit der version von sdoubleyou vergleichen
_________________
Ein Ring, sie zu knechten, sie alle zu finden,
Ins Dunkel zu treiben und ewig zu binden
Im Lande Mordor, wo die Schatten drohn. |
|
| Back to top |
|
|
sdoubleyou
n00b
Joined: 27 May 2016
Posts: 42
|
| Posted: Thu Aug 24, 2017 6:40 pm Post subject: |
|
|
also, wenn ich locale vimrc eingebe, dann bekomme ich fast das gleiche Ergebnis
| Code: | /etc/vim/vimrc
/home/sdoubleyou/.vimrc
/home/sdoubleyou/.backups/.vimrc.bak
/home/sdoubleyou/.local/share/RecentDocuments/.vimrc.desktop
/home/sdoubleyou/.vim/bundle/vundle/test/vimrc
/usr/portage/app-editors/gvim/files/gvimrc-r1
/usr/portage/app-editors/vim-core/files/vimrc-r5
/usr/share/doc/llvm-3.9.1-r1/vimrc.bz2
/usr/share/vim/vim80/gvimrc_example.vim
/usr/share/vim/vim80/vimrc_example.vim |
Hast du die /etc/vim/vimrc.local selber angelegt gehabt?
Du kannst ja mal meine .vimrc antesten wegen den syntax. Ist einfach gehalten. Evtl. must du die Zeile "colo molokai" auskommentieren
Nutze vim nur für den täglichen Bedarf. Bin ja kein Progger 
| Code: | "#######################################################################
"
" ~/.vimrc
" vim Konfigurationsdatei
"
"
"#######################################################################
"#######################################################################
" Einstellungen
"set nocompatible " VIM-Zusätze aktivieren
set nocompatible
set encoding=utf8 " UTF8 als Zeichensatz
set mouse=a " Mausunterstüzung aktivieren
set number " Zeilennummern angeben
set incsearch " Zeigt Suchergebnisse während dem Suchen an
set hlsearch " Suchresultate farbig hervorheben
set ignorecase " Ignoriert Gross/Kleinschreibung beim Suchen
set smartcase " Nur Gross/Kleinschreibung beachten, wenn Grossbuchstabe vorhanden
set autoread " Liest die Datei neu, wenn ausserhalb von VIM geändert.
set backup " Erstellt eine Backup-Datei
set backupdir=~/.backups
set backupext=.bak
set tabstop=2 " Tabulator entspricht 2 Leerzeichen
set softtabstop=2 " Weicher Tabulator
set shiftwidth=2 " Einrücktiefe
set autoindent " Automatisch einrücken
set expandtab " Tabulatoren in Spaces umwandeln
set nowrap " Zeilenumbruch deaktivieren
"set wrap " Zeilenumbruch aktivieren
set list " listchars anzeigen
set ruler
set laststatus=2
set statusline=\%F%m%r%h\ %w\ \ CWD:\ %r%{getcwd()}%h\ \ \ Line:\ %l
set fileencodings=ucs-bom,utf-8,default,latin1
set helplang=de
set history=1000
set hlsearch
set incsearch
set listchars=tab:»·,trail:·
"set ruler
set showcmd
set showmatch
set smartcase
set smartindent
set cursorline
filetype plugin indent on
"au FileType vo_base :Voom vimoutliner
"au BufEnter *.otl setlocal tabstop=2
"au BufEnter *.otl setlocal shiftwidth=2
autocmd BufRead *.otl loadview
autocmd BufWinLeave *.otl mkview
set listchars=tab:»·,trail:· " Tabs und Leerzeichen am Zeilenende anzeigen
set t_CO=256
colo molokai
"
syntax on " Code farbig darstellen
"#######################################################################
" Makros
map <F12> :w!<CR>:!aspell --lang=de check %<CR>:e! %<CR>
"map <F5> :w! <CR>:! pdflatex % <CR>
map <F2> i########################################################################<CR><ESC>
map <F3> i#!/bin/sh<CR><ESC>
map <F4> :r!date +\%Y-\%m-\%d_\%H-\%M-\%S<CR>
filetype plugin indent on
" EOF
|
Weiterhin gebe ich dir mal die syncolor.vim http://dpaste.com/1M0DT65
Kannst Du auch mal mit https://github.com/vim/vim/blob/master/runtime/syntax/syncolor.vim vergleichen |
|
| Back to top |
|
|
franzf
Advocate
Joined: 29 Mar 2005
Posts: 4565
|
| Posted: Sun Sep 10, 2017 8:46 am Post subject: |
|
|
Bitte zeig mal auch deine vimrc.local, denn die wird gefunden, gelesen und wirft nen Fehler.
Hast du denn die /etc/vim/vimrc in dein $HOME kopiert und angepasst? Wenn ja kannst du mal mit diff zeigen, welche Änderungen eingeflossen sind?
Auch schön zu wissen wäre deine installierte vim-Version.
// edit: Ganz spontane Eingebung: Du hast nicht zufällig die /etc/vim/vimrc nach /etc/vim/vimrc.local kopiert? |
|
| Back to top |
|
|
uhai
Veteran
Joined: 23 Aug 2007
Posts: 1395
Location: Eppingen, Germany
|
| Posted: Sat Sep 23, 2017 3:07 pm Post subject: |
|
|
Was ich gemacht habe, weis sich nicht mehr....
Hier ist mal meine vimrc.local:
| Code: | scriptencoding utf-8
2 " ^^ Please leave the above line at the start of the file.
3
4 " Default configuration file for Vim
5
6 " Written by Aron Griffis <agriffis@gentoo.org>
7 " Modified by Ryan Phillips <rphillips@gentoo.org>
8 " Modified some more by Ciaran McCreesh <ciaranm@gentoo.org>
9 " Added Redhat's vimrc info by Seemant Kulleen <seemant@gentoo.org>
10
11 " You can override any of these settings on a global basis via the
12 " "/etc/vim/vimrc.local" file, and on a per-user basis via "~/.vimrc". You may
13 " need to create these.
14
15 " {{{ General settings
16 " The following are some sensible defaults for Vim for most users.
17 " We attempt to change as little as possible from Vim's defaults,
18 " deviating only where it makes sense
19 set nocompatible " Use Vim defaults (much better!)
20 set bs=2 " Allow backspacing over everything in insert mode
21 set ai " Always set auto-indenting on
22 set history=50 " keep 50 lines of command history
23 set ruler " Show the cursor position all the time
24
25 set viminfo='20,\"500 " Keep a .viminfo file.
26 set number " 2017-04-16 Zeilennummerierung einschalten
27 set cursorline " 2017-04-16 Zeile mit Cursor markieren
28 set cursorcolumn " 2017-04-16 Spalte mit Cursor markieren
29
30 " Don't use Ex mode, use Q for formatting
31 map Q gq
32
33 " When doing tab completion, give the following files lower priority. You may
34 " wish to set 'wildignore' to completely ignore files, and 'wildmenu' to enable
35 " enhanced tab completion. These can be done in the user vimrc file.
36 set suffixes+=.info,.aux,.log,.dvi,.bbl,.out,.o,.lo
37
38 " When displaying line numbers, don't use an annoyingly wide number column. This
39 " doesn't enable line numbers -- :set number will do that. The value given is a
40 " minimum width to use for the number column, not a fixed size.
41 if v:version >= 700
42 set numberwidth=3
43 endif
44 " }}}
45
46 " {{{ Modeline settings
47 " We don't allow modelines by default. See bug #14088 and bug #73715.
48 " If you're not concerned about these, you can enable them on a per-user
49 " basis by adding "set modeline" to your ~/.vimrc file.
50 set nomodeline
51 " }}}
52
53 " {{{ Locale settings
54 " Try to come up with some nice sane GUI fonts. Also try to set a sensible
55 " value for fileencodings based upon locale. These can all be overridden in
56 " the user vimrc file.
57 if v:lang =~? "^ko"
58 set fileencodings=euc-kr
59 set guifontset=-*-*-medium-r-normal--16-*-*-*-*-*-*-*
60 elseif v:lang =~? "^ja_JP"
61 set fileencodings=euc-jp
62 set guifontset=-misc-fixed-medium-r-normal--14-*-*-*-*-*-*-*
63 elseif v:lang =~? "^zh_TW"
64 set fileencodings=big5
65 set guifontset=-sony-fixed-medium-r-normal--16-150-75-75-c-80-iso8859-1,-taipei-fixed-medium-r-normal--16-150-75-75-c-160-big5-0
66 elseif v:lang =~? "^zh_CN"
67 set fileencodings=gb2312
68 set guifontset=*-r-*
69 endif
70
71 " If we have a BOM, always honour that rather than trying to guess.
72 if &fileencodings !~? "ucs-bom"
73 set fileencodings^=ucs-bom
74 endif
75
76 " Always check for UTF-8 when trying to determine encodings.
77 if &fileencodings !~? "utf-8"
78 " If we have to add this, the default encoding is not Unicode.
79 " We use this fact later to revert to the default encoding in plaintext/empty
80 " files.
81 let g:added_fenc_utf8 = 1
82 set fileencodings+=utf-8
83 endif
84
85 " Make sure we have a sane fallback for encoding detection
86 if &fileencodings !~? "default"
87 set fileencodings+=default
88 endif
89 " }}}
90
91 " {{{ Syntax highlighting settings
92 " Switch syntax highlighting on, when the terminal has colors
93 " Also switch on highlighting the last used search pattern.
94 if &t_Co > 2 || has("gui_running")
95 syntax on
96 set hlsearch
97 endif
98 " }}}
99
100 " {{{ Terminal fixes
101 if &term ==? "xterm"
102 set t_Sb=^[4%dm
103 set t_Sf=^[3%dm
104 set ttymouse=xterm2
105 endif
106
107 if &term ==? "gnome" && has("eval")
108 " Set useful keys that vim doesn't discover via termcap but are in the
109 " builtin xterm termcap. See bug #122562. We use exec to avoid having to
110 " include raw escapes in the file.
111 exec "set <C-Left>=\eO5D"
112 exec "set <C-Right>=\eO5C"
113 endif
114 " }}}
115
116 " {{{ Filetype plugin settings
117 " Enable plugin-provided filetype settings, but only if the ftplugin
118 " directory exists (which it won't on livecds, for example).
119 if isdirectory(expand("$VIMRUNTIME/ftplugin"))
120 filetype plugin on
121
122 " Uncomment the next line (or copy to your ~/.vimrc) for plugin-provided
123 " indent settings. Some people don't like these, so we won't turn them on by
124 " default.
125 filetype indent on " 2017-04-16 Automatische Einrückungen einschalten
126 endif
127 " }}}
128
129 " {{{ Fix &shell, see bug #101665.
130 if "" == &shell
131 if executable("/bin/bash")
132 set shell=/bin/bash
133 elseif executable("/bin/sh")
134 set shell=/bin/sh
135 endif
136 endif
137 "}}}
138
139 " {{{ Our default /bin/sh is bash, not ksh, so syntax highlighting for .sh
140 " files should default to bash. See :help sh-syntax and bug #101819.
141 if has("eval")
142 let is_bash=1
143 endif
144 " }}}
145
146 " {{{ Autocommands
147 if has("autocmd")
148
149 augroup gentoo
150 au!
151
152 " Gentoo-specific settings for ebuilds. These are the federally-mandated
153 " required tab settings. See the following for more information:
154 " http://www.gentoo.org/proj/en/devrel/handbook/handbook.xml
155 " Note that the rules below are very minimal and don't cover everything.
156 " Better to emerge app-vim/gentoo-syntax, which provides full syntax,
157 " filetype and indent settings for all things Gentoo.
158 au BufRead,BufNewFile *.e{build,class} let is_bash=1|setfiletype sh
159 au BufRead,BufNewFile *.e{build,class} set ts=4 sw=4 noexpandtab
160
161 " In text files, limit the width of text to 78 characters, but be careful
162 " that we don't override the user's setting.
163 autocmd BufNewFile,BufRead *.txt
164 \ if &tw == 0 && ! exists("g:leave_my_textwidth_alone") |
165 \ setlocal textwidth=78 |
166 \ endif
167
168 " When editing a file, always jump to the last cursor position
169 autocmd BufReadPost *
170 \ if ! exists("g:leave_my_cursor_position_alone") |
171 \ if line("'\"") > 0 && line ("'\"") <= line("$") |
172 \ exe "normal! g'\"" |
173 \ endif |
174 \ endif
175
176 " When editing a crontab file, set backupcopy to yes rather than auto. See
177 " :help crontab and bug #53437.
178 autocmd FileType crontab set backupcopy=yes
179
180 " If we previously detected that the default encoding is not UTF-8
181 " (g:added_fenc_utf8), assume that a file with only ASCII characters (or no
182 " characters at all) isn't a Unicode file, but is in the default encoding.
183 " Except of course if a byte-order mark is in effect.
184 autocmd BufReadPost *
185 \ if exists("g:added_fenc_utf8") && &fileencoding == "utf-8" &&
186 \ ! &bomb && search('[\x80-\xFF]','nw') == 0 && &modifiable |
187 \ set fileencoding= |
188 \ endif
189
190 augroup END
191
192 endif " has("autocmd")
193 " }}}
194
195 " We don't want VIM to load their own built-in defaults, preferring ours here
196 " instead:
197 let g:skip_defaults_vim = 1
198
199 " {{{ vimrc.local
200 if filereadable("/etc/vim/vimrc.local")
201 source /etc/vim/vimrc.local
202 endif
203 " }}}
204
205 " vim: set fenc=utf-8 tw=80 sw=2 sts=2 et foldmethod=marker :
206 |
Ein locate .vimrc ergibt hier keine Treffer !?
uhai |
|
| Back to top |
|
|
franzf
Advocate
Joined: 29 Mar 2005
Posts: 4565
|
| Posted: Sat Sep 23, 2017 6:53 pm Post subject: |
|
|
Ha! Da lag ich mit meinem EDIT ja goldrichtig!
Schau dir in deiner vimrc.local die Zeilen 200-202 an und überleg GENAU was da passiert. Beim ersten mal. beim zweiten mal. beim dritten mal... Stichwort Rekursion (was ja auch direkt was mit der Fehlermeldung zu tun hat ) |
|
| Back to top |
|
|
franzf
Advocate
Joined: 29 Mar 2005
Posts: 4565
|
| Posted: Sat Sep 23, 2017 6:55 pm Post subject: |
|
|
| uhai wrote: | | Ein locate .vimrc ergibt hier keine Treffer !? |
locate arbeitet mit einer Datenbank und nicht direkt im Dateisystem. Man muss locate konfigurieren und alle Pfade eintragen, die indiziert werden sollen. Danach mit updatedb aktualisieren. Wahrsceinlich ist bei dir /etc nicht als zu indizierender Pfad registriert, drum wird auch nichts gefunden. |
|
| Back to top |
|
|
uhai
Veteran
Joined: 23 Aug 2007
Posts: 1395
Location: Eppingen, Germany
|
| Posted: Sat Sep 23, 2017 7:59 pm Post subject: |
|
|
super Franzf, das war es.
locate und updatedb arbeiten doch zusammen. Konfiguriert wird updatedb in /etc/updatedb.conf. Da isnd bei mir allerdings keine pfade angegeben die durchsucht oder nicht durchsucht werden sollen.
Gibt es noch eine Konfigurationsdatei?
uhai |
|
| Back to top |
|
|
franzf
Advocate
Joined: 29 Mar 2005
Posts: 4565
|
| Posted: Mon Sep 25, 2017 11:05 am Post subject: |
|
|
Wg. locate lag ich etwas falsch (zu meiner Verteidung: Hab das zum letzten mal vor 15 Jahren verwendet...) - man muss wohl AUSSCHLIESSEN was man nicht haben will. man updatedb.conf
Und ich nehme an, dass du einfach in deinem $HOME keine eigene .vimrc hast sondern immer noch die globale /etc/vim/vimrc verwendest - die sollte dann mit locate vimrc gefunden werden, locate .vimrc wird die wahrscheinlich nicht finden...
(Alternativ: Du hast irgendwann /home in der updatedb.conf ausgeschlossen. Lässt sich schnell herausfinden mit nem Blick in die updatedb.conf) |
|
| Back to top |
|
|
|
|
You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum
|
|
Deutsches Forum (German)
