blinker
n00b
Joined: 21 Aug 2009
Posts: 14
|
 Posted: Fri Feb 14, 2025 9:01 pm Post subject: Portage ebuild to github branch possible? |
 |
|
Hello,
Last year media-sound/exaile was removed from portage because of a dependency on a package (Berkeley) deprecated in gentoo and fedora.
Recently, on the exaile github, someone created a branch that no longer depends on the Berkeley dependency
I adapted the old 9999 ebuild to use this branch and can compile and use exaile fine on my bran-new gentoo install.
My question is :
Would it be accepted to include an ebuild in portage if it is based on an github sub branch and not the main branch ?
If so, how would one proceed to remove the last right bug like this one https://bugs.gentoo.org/922816
Open a new bug? Submit a request somewhere else ?
More info on this in the exaile issue https://github.com/exaile/exaile/issues/915
The original ebiuld was taken here
https://gitweb.gentoo.org/repo/gentoo.git/tree/media-sound/exaile/exaile-9999.ebuild?id=5a2a98c5eeb0728e3b22945a1af523b93bbeb089
My new version is like this
| Code: | # Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{9..12} )
PYTHON_REQ_USE="sqlite"
inherit python-single-r1 xdg
if [[ ${PV} == "9999" ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/exaile/exaile.git"
EGIT_BRANCH="sqlite"
else
SRC_URI="https://github.com/${PN}/${PN}/archive/${PV/_/-}/${PN}-${PV/_/}.tar.gz"
KEYWORDS="~amd64 ~x86"
S="${WORKDIR}/${PN}-${PV/_/-}"
fi
DESCRIPTION="GTK+ based media player aiming to be similar to Amarok"
HOMEPAGE="https://www.exaile.org/"
LICENSE="GPL-2 GPL-3"
SLOT="0"
# IUSE+=cddb if have dev-python/cddb-py
IUSE="libnotify nls scrobbler"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
BDEPEND="
nls? (
dev-util/intltool
sys-devel/gettext
)
"
RDEPEND="${PYTHON_DEPS}
media-libs/gst-plugins-base:1.0
media-libs/gst-plugins-good:1.0
media-plugins/gst-plugins-meta:1.0
x11-libs/gtk+:3[introspection]
libnotify? ( x11-libs/libnotify[introspection] )
$(python_gen_cond_dep '
dev-python/dbus-python[${PYTHON_USEDEP}]
dev-python/gst-python:1.0[${PYTHON_USEDEP}]
dev-python/pycairo[${PYTHON_USEDEP}]
dev-python/pygobject:3[${PYTHON_USEDEP}]
media-libs/mutagen[${PYTHON_USEDEP}]
scrobbler? ( dev-python/pylast[${PYTHON_USEDEP}] )
')
"
# dev-python/bsddb3[${PYTHON_USEDEP}]
RESTRICT="test" #315589
pkg_setup() {
python-single-r1_pkg_setup
}
src_compile() {
use nls && emake locale
}
src_install() {
emake \
PREFIX=/usr \
LIBINSTALLDIR=/usr/$(get_libdir) \
DESTDIR="${D}" \
install$(use nls || echo _no_locale)
python_optimize "${D}/usr/$(get_libdir)/${PN}"
python_optimize "${D}/usr/share/${PN}"
} |
Thanks |
|
Unsupported Software
