View previous topic :: View next topic |
Author |
Message |
Daemonfly n00b
Joined: 31 Jan 2003 Posts: 46 Location: Pa - USA
|
Posted: Wed Jul 14, 2004 5:46 am Post subject: software for PAL DVD to NTSC DVDR? |
|
|
Need some software to help rip a Pal DVD to NTSC.
I have an import thats PAL, works fine in the PC, but I'd like to use it on my stand-alone player (Toshiba), but it doesn't accept PAL discs. I would like to rip it, then convert to NTSC and burn to a DVD for a personal NTSC copy without any loss of quality.
Any suggestions? |
|
Back to top |
|
|
pharaoh Apprentice
Joined: 20 Nov 2003 Posts: 211 Location: Pennsylvania
|
Posted: Tue Oct 26, 2004 10:41 pm Post subject: |
|
|
I'm looking around to do the same thing...did you get anywhere with this before? _________________ RYZEN 5 3600 Matisse (Zen 2) 6-Core 3.6 GHz Socket AM4 65W
ASRock B550M PRO4
Crucial Ballistix 3200 MHz DDR4 DRAM 16GB
EVGA GeForce GTX 1060 6GB |
|
Back to top |
|
|
robinmarlow Apprentice
Joined: 10 Mar 2004 Posts: 167
|
Posted: Wed Oct 27, 2004 9:43 am Post subject: |
|
|
I've never done exactly what you want to - but i have made dvds from scratch & converted NTSC avi to PAL DVD.
What i would do would be to rip the dvd with dvd::rip, unfortunately from what i can see the lovely transcode options within dvd:rip will only let you convert it into VCD / SVCD.
so you need to find where it ripped the vobs to, then use transcode with something like:
transcode -i /home/robin/films/whatever.vob -V -y mpeg -F d -Z 720x576
-J fps=23.976:25 -export_fps 25 --export_asr 2 -E 48000 -b 224 -o whatever
i'm not sure about the -Z, you may want to do something else there & the 23.976 need to be the framerate of the source file (read the output of mplayer when playing the file).
then mplex the whatever.m2v & .mpa into a mpeg file
mplex -f 8 -o whatever.mpg whatever.m2v whatever.mpa
i think that should give you pal mpegs with no quality loss.
I don't know how you would go about using the original menu though.
qdvdauthor is very good (although it tends to crash occasionally) for making menus from scratch.
good webpage on converting .avi to dvd is:
http://mightylegends.zapto.org/dvd/dvdauthor_howto.php |
|
Back to top |
|
|
sekopaa n00b
Joined: 03 Jun 2004 Posts: 10 Location: Suomi
|
Posted: Fri Nov 26, 2004 10:10 pm Post subject: |
|
|
I used to live in London for a while and spent alot of time doing this when I got back. I wrote a script a while ago to do just this. It's written in csh but it worked... Anyway I can't remember exactly what all the options ment, but you welcome to use the script... If I remember, one of the most important things was to de-interlace the video or your result will be jumpy. (This is done with yuvdenoise, see the script...).
Also, I forgot how I got the number of titles (some command line utility), but you can just get this info from dvdrip...
Code: |
#!/bin/csh
#
# 16:9 PAL to 16:9 NTSC conversion script.
#
# Usage: pal2ntsc_wide [project name] [# of titles] check (optional)
#
# Description: This script uses mplayer and mjpegtools to convert
# PAL anamorphic or widescreen to NTSC widescreen.
# If the last parameter is "check" then the commands
# are only echoed, not run.
#
# Output: This script ouputs the converted video into MPEG2 stream (.m2v)
# and the audio into a Dolby digital file (.ac3). These can then
# be multiplexed into a .vob by mplex or used in an authoring
# program such as DVD Studio Pro or dvdauthor.
#
# Author: Ryan Graham (just the script, not the real stuff...)
# Licensed under the GPL version 2
if ($#argv == 3) then
if($3 == check) then
set prjnam = $1
set tcount = $2
set doit = 0
else
echo "Usage: pal2ntsc_wide [project name] [# of titles] check (optional)"
echo " INFO: check - only echos commands"
exit 1
endif
else if ($#argv == 2) then
set prjnam = $1
set tcount = $2
set doit = 1
else
echo "Usage: pal2ntsc_wide [project name] [# of titles] check (optional)"
echo " INFO: check - only echos commands"
exit 1
endif
#----------------------------------------------------------#
# Make the project directory. #
#----------------------------------------------------------#
echo "mkdir $prjnam"
if ($doit == 1) then
mkdir $prjnam
endif
#----------------------------------------------------------#
# Rip the titles from the dvd. #
#----------------------------------------------------------#
set i = 0
while ($i != $tcount)
@ i ++
set tdir = $prjnam/title$i
echo "mkdir $tdir"
if ($doit == 1) then
mkdir $tdir
endif
echo "cd $tdir"
if ($doit == 1) then
cd $tdir
endif
echo "mplayer -dvd $i -dumpstream -dumpfile title$i.vob"
if ($doit == 1) then
mplayer -dvd $i -dumpstream -dumpfile title$i.vob
endif
echo "cd ../.."
if ($doit == 1) then
cd ../..
endif
end
#----------------------------------------------------------#
# Dump the audio and encode each title. #
#----------------------------------------------------------#
set i = 0
while ($i != $tcount)
@ i ++
set tdir = $prjnam/title$i
echo "cd $tdir"
if ($doit == 1) then
cd $tdir
endif
# dump the audio
#-------------------------------------------------------
echo "mplayer -dumpaudio -dumpfile title$i.ac3 title$i.vob"
if ($doit == 1) then
mplayer -dumpaudio -dumpfile title$i.ac3 title$i.vob
endif
# Create a YUV video stream and pump the .vob through
# it. This needs to be run in the background.
#--------------------------------------------------------
echo "mkfifo stream.yuv"
if ($doit == 1) then
mkfifo stream.yuv
endif
echo "(mplayer -vo yuv4mpeg -nosound -noframedrop title$i.vob >& mkstream.log) &"
if ($doit == 1) then
(mplayer -vo yuv4mpeg -nosound -noframedrop title$i.vob >& mkstream.log) &
endif
# De-interlace, change the frame rate, scale, and encode
# the stream.
#--------------------------------------------------------
echo "(yuvdenoise -F <stream.yuv | \\"
echo " yuvfps -r 30000:1001 | \\"
echo " yuvscaler -M WIDE2STD -O DVD | \\"
echo " mpeg2enc -f 8 -q 5 -b 8500 -n n -I 0 -R 2 -4 2 -2 1 \\"
echo " -c -K tmpgenc -o title$i.m2v) >& pal2ntsc.log"
if ($doit == 1) then
(yuvdenoise -F <stream.yuv | \
yuvfps -r 30000:1001 | \
yuvscaler -M WIDE2STD -O DVD | \
mpeg2enc -f 8 -q 5 -b 8500 -n n -I 0 -R 2 -4 2 -2 1 \
-c -K tmpgenc -o title$i.m2v) >& pal2ntsc.log
endif
echo "cd ../.."
if ($doit == 1) then
cd ../..
endif
end
|
_________________ You do ill if you praise, but worse if you censure, what you do not understand.
- Leonardo da Vinci |
|
Back to top |
|
|
tuxicated Tux's lil' helper
Joined: 02 Nov 2004 Posts: 120
|
|
Back to top |
|
|
|